We author batch files that our Build Managers can use to compile all of our binaries, but I recently ran into a issue where I wanted to give them an option of providing some, or all, of the arguments needed to run the batch file.  If some were left out, then I would use some kind of default values.

Because of this, I wanted to use the command line pattern of -arg1=value1 -arg2=value2, which is not natively supported in a simple batch file.  Furthermore, I didn’t want to force a set sequence, so they could also use -arg2=value2 -arg1=value1.

It took some creative license (i.e. hacks) to get this to work correctly, but now I can use a standard command line argument pattern when creating these batch files.

Here’s the complete solution.

************************
UPDATE: I also added in the ability to provide option flags in addition to name/value pairs.

Syntax:  BATCH -project=MyProject -target=compile -sdkpath=C:\Flex\sdk -e -o
************************

ECHO OFF
CLS

REM =============================================================================
REM  Set default (empty) values for the variables that will be used to hold the
REM  values specified in the command line arguments.
REM =============================================================================
SET PROJECT=
SET TARGET=
SET SDKPATH=
SET EMAILLOG=
SET REMOTE=false

:PARSEARGUMENTS

REM =============================================================================
REM  Concatenate arguments 1 and 2 with an equals sign unless it is an option
REM  flag which we determine by looking at %2 and seeing if it starts with -
REM =============================================================================
SET ARGUMENT2=%2
if "%ARGUMENT2:~0,1%" == "-" (
    SET commandline=%1=
    SET ARGUMENTTYPE=single
) else (
    SET commandline=%1=%2
    SET ARGUMENTTYPE=double
)

REM =============================================================================
REM  If the first argument is just an equals sign, we've parsed all the arguments
REM =============================================================================
IF "commandline%" == "=" GOTO DONEPARSING

REM =============================================================================
REM  Clear out the values for the switch and the value
REM =============================================================================
SET SWITCH=
SET VALUE=

REM =============================================================================
REM  Using the equals sign as the delimiter, set the SWITCH variable to the
REM  argument name, and the VALUE variable to the argument value
REM =============================================================================
FOR /f "tokens=1,2 delims==" %%a IN ("%commandline%") DO SET SWITCH=%%a&SET VALUE=%%b

REM =============================================================================
REM  Put an IF condition for each command line argument that you are expecting
REM  on the command line, and set the corresponding variable to what's contained
REM  in the VALUE variable.
REM
REM  Then use the SHIFT command twice to move to the next name/value pair.
REM =============================================================================
IF "%SWITCH%" == "-sdkpath" (
    SET SDKPATH=%VALUE%
    GOTO SHIFTER
) 

IF "%SWITCH%" == "-target" (
    SET TARGET=%VALUE%
    GOTO SHIFTER
)

IF "%SWITCH%" == "-project" (
    SET PROJECT=%VALUE%
    GOTO SHIFTER
)

IF "%SWITCH%" == "-e" (
    SET EMAILLOG=yes
    GOTO SHIFTER
)

:SHIFTER
IF "%ARGUMENTTYPE%" == "single" (
    SHIFT
) ELSE (
    SHIFT
    SHIFT
)

REM =============================================================================
REM  Start the parsing process all over again.
REM =============================================================================
GOTO PARSEARGUMENTS

:DONEPARSING

I’ve used several automated build tools over these many years, and even though I’ve only been using TeamCity for <24 hours, I can honestly say it's the easiest one I've ever used.

During 2 hours last night, and 3 hours this morning, I was able to set up every project we have, convert the Ant scripts, establish the proper dependencies, and have build triggers set up for each one.

Additionally, the Eclipse plugin they made is professional and bug-free. Here's a quick screenshot I took last night while I was getting all the projects configured.

It even includes support for Jabber, so I’m installing a test server on my machine to see how that works. Hard to imagine that I could have a complete build management server set up, including notifications, and integration with task management within 48 hours – cuz that’s how long I think it’s going to take.